1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
|
// Type for data
type T = bv4;
const N: int; axiom N == 4;
const one: T; axiom one == 1bv4;
// helper operations
function {:inline} xor(a: bool, b: bool) returns (bool) { (!a && b) || (a && !b) }
function {:bvbuiltin "bvxor"} xorT(p1: T, p2: T) : T;
function {:bvbuiltin "bvult"} bv2lt(p1: bv2, p2: bv2) : bool;
function {:bvbuiltin "bvult"} bvlt(p1: T, p2: T) : bool; // unsigned less than
function {:bvbuiltin "bvlshr"} shiftrightAny(p1: T, n: T) : T; // shift right
function {:inline} shiftright(p1: T) : T { shiftrightAny(p1, one) }
function bv2bool(x: bv1) : bool { if (x == 0bv1) then false else true }
// Oblivious Transfer
procedure ObliviousTransfer(
{:visible "A"} m0: T, {:visible "A"} m1: T,
{:visible "B"} c: bool)
returns ({:visible "B"} m: T)
// spec
ensures (m == if c then m1 else m0);
// Implementation
{
var {:visible "A"} m0p, m1p: T;
var {:visible "B"} mp: T;
var {:visible "B"} cp: bool;
var x: bool;
var y, z: T;
havoc cp;
havoc m0p, m1p;
mp := if cp then m0p else m1p;
x := xor(c, cp);
y := xorT(m0, if x then m0p else m1p);
z := xorT(m1, if x then m1p else m0p);
m := xorT(if c then z else y, mp);
}
// Oblivious Transfer for Bools
procedure ObliviousTransferBool(
{:visible "A"} m0: bool, {:visible "A"} m1: bool,
{:visible "B"} c: bool)
returns ({:visible "B"} m: bool);
// spec
free ensures (m == if c then m1 else m0);
// Lover's Protocol 1
procedure LoversProtocol1(
{:visible "A"} a: bool, {:visible "B"} b: bool)
returns ({:visible "A"} ap: bool, {:visible "B"} bp: bool)
// spec
ensures xor(ap, bp) == (a && b);
{
havoc ap;
call bp := ObliviousTransferBool(ap, xor(a, ap), b);
}
// Lover's Protocol 1 Modified
procedure LoversProtocol1Modified(
{:visible "A"} a: bool, {:visible "B"} b: bool)
returns ({:visible "A"} ap: bool, {:visible "B"} bp: bool)
// spec
ensures xor(ap, bp) == xor(a, b);
{
var {:visible "B"} bpp: bool;
havoc ap;
bpp := xor(ap, a);
bp := xor(bpp, b);
}
// Lover's Protocol 2
procedure LoversProtocol2(
{:visible "A"} aA: bool, {:visible "A"} bA: bool,
{:visible "B"} aB: bool, {:visible "B"} bB: bool)
returns ({:visible "A"} ap: bool, {:visible "B"} bp: bool)
// spec
ensures xor(ap, bp) == (xor(aA, aB) && xor(bA, bB));
{
var {:visible "A"} rA, wA: bool;
var {:visible "B"} rB, wB: bool;
call rA, wA := LoversProtocol1(aA, bB);
call rB, wB := LoversProtocol1(aB, bA);
ap := xor(xor(aA && bA, rA), wA);
bp := xor(xor(wB, rB), aB && bB);
}
// While functionally correct, this isn't secure
procedure Incorrect(
{:visible "A"} a: bool, {:visible "B"} b: bool)
returns ({:visible "A"} ap: bool, {:visible "B"} bp: bool)
// spec
ensures xor(ap, bp) == xor(a, b);
{
ap := a;
bp := b;
}
procedure TwoBitMillionaires(
{:visible "A"} a: bv2, {:visible "B"} b: bv2)
returns ({:visible "A"} ap: bool, {:visible "B"} bp: bool)
ensures xor(ap, bp) == bv2lt(a, b);
{
var {:visible "A"} a0, a1: bool;
var {:visible "B"} b0, b1: bool;
// Extract bits
a0 := bv2bool(a[1:0]);
a1 := bv2bool(a[2:1]);
b0 := bv2bool(b[1:0]);
b1 := bv2bool(b[2:1]);
call ap, bp := TwoBitMillionairesExplicit(a0, a1, b0, b1);
}
procedure TwoBitMillionairesExplicit(
{:visible "A"} a0: bool, {:visible "A"} a1: bool,
{:visible "B"} b0: bool, {:visible "B"} b1: bool)
returns ({:visible "A"} ap: bool, {:visible "B"} bp: bool)
ensures xor(ap, bp) == xor(!a1 && b1, (a1 == b1) && (!a0 && b0));
{
var {:visible "A"} aA, bA, wA: bool;
var {:visible "B"} aB, bB, wB: bool;
call aA, aB := LoversProtocol1(!a1, b1);
call wA, wB := LoversProtocol1(!a0, b0);
call bA, bB := LoversProtocol2(!a1, wA, b1, wB);
ap := xor(aA, bA);
bp := xor(aB, bB);
}
procedure TwoBitMillionairesExplicitModified(
{:visible "A"} a0: bool, {:visible "A"} a1: bool,
{:visible "B"} b0: bool, {:visible "B"} b1: bool)
returns ({:visible "A"} ap: bool, {:visible "B"} bp: bool)
ensures xor(ap, bp) == xor(!a1 && b1, (a1 == b1) && xor(a0, b0));
{
var {:visible "A"} aA, bA, wA: bool;
var {:visible "B"} aB, bB, wB: bool;
call aA, aB := LoversProtocol1(!a1, b1);
call wA, wB := LoversProtocol1Modified(a0, b0);
call bA, bB := LoversProtocol2(!a1, wA, b1, wB);
ap := xor(aA, bA);
bp := xor(aB, bB);
}
procedure NBitMillionaires(
{:visible "A"} a: T, {:visible "B"} b: T)
returns ({:visible "A"} la: bool, {:visible "B"} lb: bool)
ensures xor(la, lb) == bvlt(a, b);
{
var n: int;
var {:visible "A"} aleft: T;
var {:visible "B"} bleft: T;
var {:visible "A"} an: bool;
var {:visible "B"} bn: bool;
n := 0;
aleft := a;
bleft := b;
havoc la, lb; assume xor(la, lb) == false;
while (n < N)
invariant true;
{
an := bv2bool(aleft[1:0]);
bn := bv2bool(bleft[1:0]);
aleft := shiftright(aleft);
bleft := shiftright(bleft);
call la, lb := TwoBitMillionairesExplicitModified(la, an, lb, bn);
n := n + 1;
}
}
|
