1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
//
// MCOAccountValidator.m
// mailcore2
//
// Created by Christopher Hockley on 20/01/15.
// Copyright (c) 2015 MailCore. All rights reserved.
//
#import "MCOAccountValidator.h"
#include "MCAccountValidator.h"
#include "MCNetService.h"
#import "MCOOperation+Private.h"
#import "MCOUtils.h"
#import "MCOperationCallback.h"
#import "MCONetService.h"
typedef void (^CompletionType)(void);
@interface MCOAccountValidator ()
- (void) _operationCompleted;
- (void) _logWithSender:(void *)sender connectionType:(MCOConnectionLogType)logType data:(NSData *)data;
@end
class MCOValidatorOperationCallback: public mailcore::Object, public mailcore::OperationCallback, public mailcore::ConnectionLogger {
public:
MCOValidatorOperationCallback(MCOAccountValidator * op)
{
mOperation = op;
}
void operationFinished(mailcore::Operation * op)
{
[mOperation _operationCompleted];
}
virtual void log(void * sender, mailcore::ConnectionLogType logType, mailcore::Data * data)
{
[mOperation _logWithSender:sender connectionType:(MCOConnectionLogType)logType data:MCO_TO_OBJC(data)];
}
private:
MCOAccountValidator * mOperation;
};
@implementation MCOAccountValidator{
CompletionType _completionBlock;
mailcore::AccountValidator * _validator;
MCOValidatorOperationCallback * _callback;
MCOConnectionLogger _connectionLogger;
}
#define nativeType mailcore::AccountValidator
+ (void) load
{
MCORegisterClass(self, &typeid(nativeType));
}
- (mailcore::Object *) mco_mcObject
{
return _validator;
}
+ (NSObject *) mco_objectWithMCObject:(mailcore::Object *)object
{
mailcore::AccountValidator * validator = (mailcore::AccountValidator *) object;
return [[[self alloc] initWithMCValidator:validator] autorelease];
}
MCO_OBJC_SYNTHESIZE_STRING(setEmail, email)
MCO_OBJC_SYNTHESIZE_STRING(setUsername, username)
MCO_OBJC_SYNTHESIZE_STRING(setPassword, password)
MCO_OBJC_SYNTHESIZE_STRING(setOAuth2Token, OAuth2Token)
MCO_OBJC_SYNTHESIZE_BOOL(setImapEnabled, isImapEnabled)
MCO_OBJC_SYNTHESIZE_BOOL(setPopEnabled, isPopEnabled)
MCO_OBJC_SYNTHESIZE_BOOL(setSmtpEnabled, isSmtpEnabled)
- (instancetype) init
{
mailcore::AccountValidator * validator = new mailcore::AccountValidator();
self = [self initWithMCValidator:validator];
validator->release();
return self;
}
- (instancetype) initWithMCValidator:(mailcore::AccountValidator *)validator
{
self = [super initWithMCOperation:validator];
_validator = validator;
_callback = new MCOValidatorOperationCallback(self);
_validator->setCallback(_callback);
_validator->retain();
return self;
}
- (void) dealloc
{
[_completionBlock release];
MC_SAFE_RELEASE(_validator);
MC_SAFE_RELEASE(_callback);
[_connectionLogger release];
[super dealloc];
}
- (void) start:(void (^)(void))completionBlock
{
_completionBlock = [completionBlock copy];
[self start];
}
- (void) cancel
{
[_completionBlock release];
_completionBlock = nil;
[super cancel];
}
- (void) _operationCompleted
{
if (_completionBlock == NULL)
return;
_completionBlock();
[_completionBlock release];
_completionBlock = nil;
}
- (NSString *) identifier
{
return MCO_OBJC_BRIDGE_GET(identifier);
}
- (MCONetService *) imapServer
{
return MCO_OBJC_BRIDGE_GET(imapServer);
}
- (MCONetService *) popServer
{
return MCO_OBJC_BRIDGE_GET(popServer);
}
- (MCONetService *) smtpServer
{
return MCO_OBJC_BRIDGE_GET(smtpServer);
}
- (NSError *) imapError
{
return [NSError mco_errorWithErrorCode:_validator->imapError()];
}
- (NSError *) popError
{
return [NSError mco_errorWithErrorCode:_validator->popError()];
}
- (NSError *) smtpError
{
return [NSError mco_errorWithErrorCode:_validator->smtpError()];
}
- (void) setConnectionLogger:(MCOConnectionLogger)connectionLogger
{
[_connectionLogger release];
_connectionLogger = [connectionLogger copy];
if (_connectionLogger != nil) {
_validator->setConnectionLogger(_callback);
}
else {
_validator->setConnectionLogger(NULL);
}
}
- (MCOConnectionLogger) connectionLogger
{
return _connectionLogger;
}
- (void) _logWithSender:(void *)sender connectionType:(MCOConnectionLogType)logType data:(NSData *)data
{
_connectionLogger(sender, logType, data);
}
@end
|
