Server Time Operations

1 files changed, 70 insertions, 0 deletions

diff --git a/src/objc/nntp/MCONNTPFetchServerTimeOperation.mm b/src/objc/nntp/MCONNTPFetchServerTimeOperation.mm
new file mode 100644
index 00000000..a2f51f91
--- /dev/null
+++ b/src/objc/nntp/MCONNTPFetchServerTimeOperation.mm
@@ -0,0 +1,70 @@
+//
+//  MCONNTPFetchServerTimeOperation.m
+//  mailcore2
+//
+//  Created by Robert Widmann on 10/21/14.
+//  Copyright (c) 2014 MailCore. All rights reserved.
+//
+
+#import "MCONNTPFetchServerTimeOperation.h"
+
+#include "MCAsyncNNTP.h"
+
+#import "MCOOperation+Private.h"
+#import "MCOUtils.h"
+
+typedef void (^CompletionType)(NSError *error, NSDate * date);
+
+@implementation MCONNTPFetchServerTimeOperation {
+    CompletionType _completionBlock;
+}
+
+#define nativeType mailcore::NNTPFetchServerTimeOperation
+
++ (void) load
+{
+    MCORegisterClass(self, &typeid(nativeType));
+}
+
++ (NSObject *) mco_objectWithMCObject:(mailcore::Object *)object
+{
+    nativeType * op = (nativeType *) object;
+    return [[[self alloc] initWithMCOperation:op] autorelease];
+}
+
+- (void) dealloc
+{
+    [_completionBlock release];
+    [super dealloc];
+}
+
+- (void) start:(void (^)(NSError *error, NSDate * date))completionBlock
+{
+    _completionBlock = [completionBlock copy];
+    [self start];
+}
+
+- (void) cancel
+{
+    [_completionBlock release];
+    _completionBlock = nil;
+    [super cancel];
+}
+
+- (void) operationCompleted
+{
+    if (_completionBlock == NULL)
+        return;
+    
+    nativeType *op = MCO_NATIVE_INSTANCE;
+    if (op->error() == mailcore::ErrorNone) {
+        _completionBlock(nil, [NSDate dateWithTimeIntervalSince1970:op->time()]);
+    } else {
+        _completionBlock([NSError mco_errorWithErrorCode:op->error()], nil);
+    }
+    [_completionBlock release];
+    _completionBlock = nil;
+}
+
+
+@end