Merge branch 'master' into removing-icu-dependency

1 files changed, 70 insertions, 0 deletions

diff --git a/src/objc/nntp/MCONNTPFetchAllArticlesOperation.mm b/src/objc/nntp/MCONNTPFetchAllArticlesOperation.mm
new file mode 100644
index 00000000..947f0324
--- /dev/null
+++ b/src/objc/nntp/MCONNTPFetchAllArticlesOperation.mm
@@ -0,0 +1,70 @@
+//
+//  MCONNTPFetchAllArticlesOperation.m
+//  mailcore2
+//
+//  Created by Robert Widmann on 8/13/14.
+//  Copyright (c) 2014 MailCore. All rights reserved.
+//
+
+#import "MCONNTPFetchAllArticlesOperation.h"
+
+#include "MCAsyncNNTP.h"
+
+#import "MCOOperation+Private.h"
+#import "MCOUtils.h"
+
+typedef void (^CompletionType)(NSError *error, MCOIndexSet * articles);
+
+@implementation MCONNTPFetchAllArticlesOperation {
+    CompletionType _completionBlock;
+}
+
+#define nativeType mailcore::NNTPFetchAllArticlesOperation
+
++ (void) load
+{
+    MCORegisterClass(self, &typeid(nativeType));
+}
+
++ (NSObject *) mco_objectWithMCObject:(mailcore::Object *)object
+{
+    nativeType * op = (nativeType *) object;
+    return [[[self alloc] initWithMCOperation:op] autorelease];
+}
+
+- (void) dealloc
+{
+    [_completionBlock release];
+    [super dealloc];
+}
+
+- (void) start:(void (^)(NSError *error, MCOIndexSet * articles))completionBlock
+{
+    _completionBlock = [completionBlock copy];
+    [self start];
+}
+
+- (void) cancel
+{
+    [_completionBlock release];
+    _completionBlock = nil;
+    [super cancel];
+}
+
+- (void) operationCompleted
+{
+    if (_completionBlock == NULL)
+        return;
+    
+    nativeType *op = MCO_NATIVE_INSTANCE;
+    if (op->error() == mailcore::ErrorNone) {
+        _completionBlock(nil, MCO_TO_OBJC(op->articles()));
+    } else {
+        _completionBlock([NSError mco_errorWithErrorCode:op->error()], nil);
+    }
+    [_completionBlock release];
+    _completionBlock = nil;
+}
+
+
+@end