blob: ca66da1fbc597432f5eb6a902b16c8dd806b1650 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
/*
* Copyright 2017 Google
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
#import "Firestore/Source/Model/FSTDocument.h"
#import "Firestore/Source/Core/FSTSnapshotVersion.h"
#import "Firestore/Source/Model/FSTDocumentKey.h"
#import "Firestore/Source/Model/FSTFieldValue.h"
#import "Firestore/Source/Util/FSTAssert.h"
#include "Firestore/core/src/firebase/firestore/model/field_path.h"
#include "Firestore/core/src/firebase/firestore/util/string_apple.h"
namespace util = firebase::firestore::util;
using firebase::firestore::model::FieldPath;
NS_ASSUME_NONNULL_BEGIN
@interface FSTMaybeDocument ()
- (instancetype)initWithKey:(FSTDocumentKey *)key
version:(FSTSnapshotVersion *)version NS_DESIGNATED_INITIALIZER;
@end
@implementation FSTMaybeDocument
- (instancetype)initWithKey:(FSTDocumentKey *)key version:(FSTSnapshotVersion *)version {
FSTAssert(!!version, @"Version must not be nil.");
self = [super init];
if (self) {
_key = key;
_version = version;
}
return self;
}
- (id)copyWithZone:(NSZone *_Nullable)zone {
// All document types are immutable
return self;
}
@end
@implementation FSTDocument
+ (instancetype)documentWithData:(FSTObjectValue *)data
key:(FSTDocumentKey *)key
version:(FSTSnapshotVersion *)version
hasLocalMutations:(BOOL)mutations {
return
[[FSTDocument alloc] initWithData:data key:key version:version hasLocalMutations:mutations];
}
- (instancetype)initWithData:(FSTObjectValue *)data
key:(FSTDocumentKey *)key
version:(FSTSnapshotVersion *)version
hasLocalMutations:(BOOL)mutations {
self = [super initWithKey:key version:version];
if (self) {
_data = data;
_localMutations = mutations;
}
return self;
}
- (BOOL)isEqual:(id)other {
if (other == self) {
return YES;
}
if (![other isKindOfClass:[FSTDocument class]]) {
return NO;
}
FSTDocument *otherDoc = other;
return [self.key isEqual:otherDoc.key] && [self.version isEqual:otherDoc.version] &&
[self.data isEqual:otherDoc.data] && self.hasLocalMutations == otherDoc.hasLocalMutations;
}
- (NSUInteger)hash {
NSUInteger result = [self.key hash];
result = result * 31 + [self.version hash];
result = result * 31 + [self.data hash];
result = result * 31 + (self.hasLocalMutations ? 1 : 0);
return result;
}
- (NSString *)description {
return [NSString stringWithFormat:@"<FSTDocument: key:%s version:%@ localMutations:%@ data:%@>",
self.key.path.CanonicalString().c_str(), self.version,
self.localMutations ? @"YES" : @"NO", self.data];
}
- (nullable FSTFieldValue *)fieldForPath:(const FieldPath &)path {
return [_data valueForPath:path];
}
@end
@implementation FSTDeletedDocument
+ (instancetype)documentWithKey:(FSTDocumentKey *)key version:(FSTSnapshotVersion *)version {
return [[FSTDeletedDocument alloc] initWithKey:key version:version];
}
- (BOOL)isEqual:(id)other {
if (other == self) {
return YES;
}
if (![other isKindOfClass:[FSTDeletedDocument class]]) {
return NO;
}
FSTDocument *otherDoc = other;
return [self.key isEqual:otherDoc.key] && [self.version isEqual:otherDoc.version];
}
- (NSUInteger)hash {
NSUInteger result = [self.key hash];
result = result * 31 + [self.version hash];
return result;
}
@end
const NSComparator FSTDocumentComparatorByKey =
^NSComparisonResult(FSTMaybeDocument *doc1, FSTMaybeDocument *doc2) {
return [doc1.key compare:doc2.key];
};
NS_ASSUME_NONNULL_END
|
