blob: 991faa9040759d72c1ae8d5d4956a7612e75b040 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
|
/*
* Copyright 2017 Google
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
#import "Firestore/Source/Local/FSTMemoryQueryCache.h"
#include <utility>
#import "Firestore/Source/Core/FSTQuery.h"
#import "Firestore/Source/Local/FSTQueryData.h"
#import "Firestore/Source/Local/FSTReferenceSet.h"
#include "Firestore/core/src/firebase/firestore/model/document_key.h"
#include "Firestore/core/src/firebase/firestore/model/snapshot_version.h"
using firebase::firestore::model::SnapshotVersion;
using firebase::firestore::model::DocumentKeySet;
NS_ASSUME_NONNULL_BEGIN
@interface FSTMemoryQueryCache ()
/** Maps a query to the data about that query. */
@property(nonatomic, strong, readonly) NSMutableDictionary<FSTQuery *, FSTQueryData *> *queries;
/** A ordered bidirectional mapping between documents and the remote target IDs. */
@property(nonatomic, strong, readonly) FSTReferenceSet *references;
/** The highest numbered target ID encountered. */
@property(nonatomic, assign) FSTTargetID highestTargetID;
@property(nonatomic, assign) FSTListenSequenceNumber highestListenSequenceNumber;
@end
@implementation FSTMemoryQueryCache {
/** The last received snapshot version. */
SnapshotVersion _lastRemoteSnapshotVersion;
}
- (instancetype)init {
if (self = [super init]) {
_queries = [NSMutableDictionary dictionary];
_references = [[FSTReferenceSet alloc] init];
_lastRemoteSnapshotVersion = SnapshotVersion::None();
}
return self;
}
#pragma mark - FSTQueryCache implementation
#pragma mark Query tracking
- (void)start {
// Nothing to do.
}
- (FSTTargetID)highestTargetID {
return _highestTargetID;
}
- (FSTListenSequenceNumber)highestListenSequenceNumber {
return _highestListenSequenceNumber;
}
- (const SnapshotVersion &)lastRemoteSnapshotVersion {
return _lastRemoteSnapshotVersion;
}
- (void)setLastRemoteSnapshotVersion:(SnapshotVersion)snapshotVersion {
_lastRemoteSnapshotVersion = std::move(snapshotVersion);
}
- (void)addQueryData:(FSTQueryData *)queryData {
self.queries[queryData.query] = queryData;
if (queryData.targetID > self.highestTargetID) {
self.highestTargetID = queryData.targetID;
}
if (queryData.sequenceNumber > self.highestListenSequenceNumber) {
self.highestListenSequenceNumber = queryData.sequenceNumber;
}
}
- (void)updateQueryData:(FSTQueryData *)queryData {
self.queries[queryData.query] = queryData;
if (queryData.targetID > self.highestTargetID) {
self.highestTargetID = queryData.targetID;
}
if (queryData.sequenceNumber > self.highestListenSequenceNumber) {
self.highestListenSequenceNumber = queryData.sequenceNumber;
}
}
- (int32_t)count {
return (int32_t)[self.queries count];
}
- (void)removeQueryData:(FSTQueryData *)queryData {
[self.queries removeObjectForKey:queryData.query];
[self.references removeReferencesForID:queryData.targetID];
}
- (nullable FSTQueryData *)queryDataForQuery:(FSTQuery *)query {
return self.queries[query];
}
#pragma mark Reference tracking
- (void)addMatchingKeys:(const DocumentKeySet &)keys forTargetID:(FSTTargetID)targetID {
[self.references addReferencesToKeys:keys forID:targetID];
}
- (void)removeMatchingKeys:(const DocumentKeySet &)keys forTargetID:(FSTTargetID)targetID {
[self.references removeReferencesToKeys:keys forID:targetID];
}
- (void)removeMatchingKeysForTargetID:(FSTTargetID)targetID {
[self.references removeReferencesForID:targetID];
}
- (DocumentKeySet)matchingKeysForTargetID:(FSTTargetID)targetID {
return [self.references referencedKeysForID:targetID];
}
#pragma mark - FSTGarbageSource implementation
- (nullable id<FSTGarbageCollector>)garbageCollector {
return self.references.garbageCollector;
}
- (void)setGarbageCollector:(nullable id<FSTGarbageCollector>)garbageCollector {
self.references.garbageCollector = garbageCollector;
}
- (BOOL)containsKey:(const firebase::firestore::model::DocumentKey &)key {
return [self.references containsKey:key];
}
@end
NS_ASSUME_NONNULL_END
|
