1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
|
/*
* Copyright 2017 Google
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
#import "Firestore/Source/Local/FSTLevelDBRemoteDocumentCache.h"
#include <leveldb/db.h>
#include <leveldb/write_batch.h>
#include <string>
#import "Firestore/Protos/objc/firestore/local/MaybeDocument.pbobjc.h"
#import "Firestore/Source/Core/FSTQuery.h"
#import "Firestore/Source/Local/FSTLevelDBKey.h"
#import "Firestore/Source/Local/FSTLocalSerializer.h"
#import "Firestore/Source/Local/FSTWriteGroup.h"
#import "Firestore/Source/Model/FSTDocument.h"
#import "Firestore/Source/Model/FSTDocumentDictionary.h"
#import "Firestore/Source/Model/FSTDocumentKey.h"
#import "Firestore/Source/Model/FSTDocumentSet.h"
#import "Firestore/Source/Model/FSTPath.h"
#import "Firestore/Source/Util/FSTAssert.h"
NS_ASSUME_NONNULL_BEGIN
using leveldb::DB;
using leveldb::Iterator;
using leveldb::ReadOptions;
using leveldb::Slice;
using leveldb::Status;
using leveldb::WriteOptions;
@interface FSTLevelDBRemoteDocumentCache ()
@property(nonatomic, strong, readonly) FSTLocalSerializer *serializer;
@end
/**
* Returns a standard set of read options.
*
* For now this is paranoid, but perhaps disable that in production builds.
*/
static ReadOptions StandardReadOptions() {
ReadOptions options;
options.verify_checksums = true;
return options;
}
@implementation FSTLevelDBRemoteDocumentCache {
// The DB pointer is shared with all cooperating LevelDB-related objects.
std::shared_ptr<DB> _db;
}
- (instancetype)initWithDB:(std::shared_ptr<DB>)db serializer:(FSTLocalSerializer *)serializer {
if (self = [super init]) {
_db = db;
_serializer = serializer;
}
return self;
}
- (void)shutdown {
_db.reset();
}
- (void)addEntry:(FSTMaybeDocument *)document group:(FSTWriteGroup *)group {
std::string key = [self remoteDocumentKey:document.key];
[group setMessage:[self.serializer encodedMaybeDocument:document] forKey:key];
}
- (void)removeEntryForKey:(FSTDocumentKey *)documentKey group:(FSTWriteGroup *)group {
std::string key = [self remoteDocumentKey:documentKey];
[group removeMessageForKey:key];
}
- (nullable FSTMaybeDocument *)entryForKey:(FSTDocumentKey *)documentKey {
std::string key = [FSTLevelDBRemoteDocumentKey keyWithDocumentKey:documentKey];
std::string value;
Status status = _db->Get(StandardReadOptions(), key, &value);
if (status.IsNotFound()) {
return nil;
} else if (status.ok()) {
return [self decodedMaybeDocument:value withKey:documentKey];
} else {
FSTFail(@"Fetch document for key (%@) failed with status: %s", documentKey,
status.ToString().c_str());
}
}
- (FSTDocumentDictionary *)documentsMatchingQuery:(FSTQuery *)query {
FSTDocumentDictionary *results = [FSTDocumentDictionary documentDictionary];
// Documents are ordered by key, so we can use a prefix scan to narrow down
// the documents we need to match the query against.
std::string startKey = [FSTLevelDBRemoteDocumentKey
keyPrefixWithResourcePath:[FSTResourcePath resourcePathWithCPPResourcePath:query.path]];
std::unique_ptr<Iterator> it(_db->NewIterator(StandardReadOptions()));
it->Seek(startKey);
FSTLevelDBRemoteDocumentKey *currentKey = [[FSTLevelDBRemoteDocumentKey alloc] init];
for (; it->Valid() && [currentKey decodeKey:it->key()]; it->Next()) {
FSTMaybeDocument *maybeDoc =
[self decodedMaybeDocument:it->value() withKey:currentKey.documentKey];
if (!query.path.IsPrefixOf(maybeDoc.key.path)) {
break;
} else if ([maybeDoc isKindOfClass:[FSTDocument class]]) {
results = [results dictionaryBySettingObject:(FSTDocument *)maybeDoc forKey:maybeDoc.key];
}
}
Status status = it->status();
if (!status.ok()) {
FSTFail(@"Find documents matching query (%@) failed with status: %s", query,
status.ToString().c_str());
}
return results;
}
- (std::string)remoteDocumentKey:(FSTDocumentKey *)key {
return [FSTLevelDBRemoteDocumentKey keyWithDocumentKey:key];
}
- (FSTMaybeDocument *)decodedMaybeDocument:(Slice)slice withKey:(FSTDocumentKey *)documentKey {
NSData *data =
[[NSData alloc] initWithBytesNoCopy:(void *)slice.data() length:slice.size() freeWhenDone:NO];
NSError *error;
FSTPBMaybeDocument *proto = [FSTPBMaybeDocument parseFromData:data error:&error];
if (!proto) {
FSTFail(@"FSTPBMaybeDocument failed to parse: %@", error);
}
FSTMaybeDocument *maybeDocument = [self.serializer decodedMaybeDocument:proto];
FSTAssert([maybeDocument.key isEqualToKey:documentKey],
@"Read document has key (%@) instead of expected key (%@).", maybeDocument.key,
documentKey);
return maybeDocument;
}
@end
NS_ASSUME_NONNULL_END
|
