path: root/configure.ac

dnl Process this file with autoconf to produce a configure script.
dnl PACKAGE=deadbeef
dnl VERSION=devel
AC_INIT([deadbeef], [devel])

AC_CONFIG_HEADER(config.h)

dnl AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
AM_INIT_AUTOMAKE([1.11 dist-bzip2])
AM_MAINTAINER_MODE()

AC_PROG_CC
AC_PROG_CXX
AC_STDC_HEADERS
AC_PROG_INSTALL
AC_PROG_LIBTOOL
AC_CONFIG_MACRO_DIR([m4])
AC_C_BIGENDIAN
if test "x$USE_MAINTAINER_MODE" = "xyes" ; then
    AM_PROG_VALAC([0.7.0])
    if test "x$VALAC" = "x" ; then
        AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])
    fi
fi

case "$host" in
  i386-*-* | i486-*-* | i586-*-* | i686-*-* | i86pc-*-*)
    AC_DEFINE(ARCH_X86_32, 1, [architecture is x86])
    ;;
  x86_64-*-* | amd64-*-*)
    AC_DEFINE(ARCH_X86_64, 1, [architecture is x86_64])
    ;;
  powerpc-*-* )
    AC_DEFINE(ARCH_PPC_32, 1, [architecture is ppc32])
    ;;
  powerpc64-*-* )
    AC_DEFINE(ARCH_PPC_64, 1, [architecture is ppc64])
    ;;
  *)
    AC_DEFINE(ARCH_UNKNOWN, 1, [architecture is unknown])
    ;;
esac

test "x$prefix" = xNONE && prefix=$ac_default_prefix

dnl INSANE_CFLAGS="-Wcomment -Wchar-subscripts -Wunused-function -Wunused-value -Wuninitialized -Wtype-limits -Wbad-function-cast"
dnl INSANE_CXXFLAGS="-Wcomment -Wchar-subscripts -Wunused-function -Wunused-value -Wuninitialized -Wtype-limits"

AC_SUBST(INSANE_CFLAGS)
AC_SUBST(INSANE_CXXFLAGS)

CXXFLAGS="$CXXFLAGS $INSANE_CXXFLAGS -D_GNU_SOURCE -DLIBDIR=\\\"$libdir\\\" -DPREFIX=\\\"$prefix\\\" -DDOCDIR=\\\"$docdir\\\""
CFLAGS="$CFLAGS $INSANE_CFLAGS -D_GNU_SOURCE -DLIBDIR=\\\"$libdir\\\" -DPREFIX=\\\"$prefix\\\" -DDOCDIR=\\\"$docdir\\\""

AC_ARG_ENABLE(libnotify, [  --enable-libnotify  Enable support for OSD notifications (default: no)], [
    if test "x$enableval" = "xyes" ; then libnotify=yes ; fi
])
if test "x${libnotify}" = "xyes" ; then
    PKG_CHECK_MODULES(NOTIFY_DEPS, libnotify >= 0.4.4, HAVE_NOTIFY=1, NO_NOTIFY=1)
fi

AC_ARG_ENABLE(nullout, [  --enable-nullout Enable NULL output plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_nullout=no ; fi])
AC_ARG_ENABLE(alsa, [  --enable-alsa  Enable ALSA output plugin (default: yes)], [ if test "x$enableval" = "xno" ; then enable_alsa=no ; fi])
AC_ARG_ENABLE(oss, [  --enable-oss  Enable Open Sound System output plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_oss=no ; fi])
AC_ARG_ENABLE(pulse, [  --enable-pulse   Enable PulseAudio output plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_pulse=no ; fi])
AC_ARG_ENABLE(gtkui, [  --enable-gtkui  Enable standard GTK2 user interface plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_gtkui=no ; fi])
AC_ARG_ENABLE(vfs_curl, [  --enable-vfs-curl  Enable HTTP streaming vfs plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_vfs_curl=no ; fi])
AC_ARG_ENABLE(lfm, [  --enable-lfm  Enable last.fm/libre.fm scrobbler plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_lfm=no ; fi])
AC_ARG_ENABLE(artwork, [  --enable-artwork  Enable album art loader plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_artwork="no" ; fi])
AC_ARG_ENABLE(supereq, [  --enable-supereq  Enable SuperEQ DSP plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_supereq="no" ;  fi])
AC_ARG_ENABLE(sid, [  --enable-sid  Enable commodore64 SID music player plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_sid="no" ; fi])
AC_ARG_ENABLE(ffap, [  --enable-ffap  Enable Monkey's Audio plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_ffap="no" ; fi])
AC_ARG_ENABLE(vtx, [  --enable-vtx  Enable libayemy VTX ZX-Spectrum music player plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_vtx="no" ; fi])
AC_ARG_ENABLE(adplug, [  --enable-adplug  Enable adplug plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_adplug="no" ; else enable_adplug="yes"; fi])
AC_ARG_ENABLE(hotkeys, [  --enable-hotkeys  Enable global hotkeys plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_hotkeys="no" ; fi])
AC_ARG_ENABLE(vorbis, [  --enable-vorbis  Enable Ogg Vorbis player plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_vorbis="no" ; fi])
AC_ARG_ENABLE(ffmpeg, [  --enable-ffmpeg  Enable FFMPEG plugin for WMA, MPC, TTA, etc (default: yes)], [if test "x$enableval" = "xno" ; then enable_ffmpeg="no" ; fi])
AC_ARG_ENABLE(flac, [  --enable-flac  Enable FLAC player plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_flac="no" ; fi])
AC_ARG_ENABLE(sndfile, [  --enable-sndfile  Enable libsndfile plugin for PCM wave files (default: yes)], [if test "x$enableval" = "xno" ; then enable_sndfile="no" ; fi])
AC_ARG_ENABLE(wavpack, [  --enable-wavpack  Enable wavpack plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_wavpack="no" ; fi])
AC_ARG_ENABLE(cdda, [  --enable-cdda  Enable CD-Audio plugin (default: yes)], [if test "x$enableval" = "xno" ; then enable_cdda="no" ; fi])

PKG_CHECK_MODULES(DEPS, samplerate)

if test "x$enable_gtkui" != "xno" ; then
    PKG_CHECK_MODULES(GTKUI_DEPS, gtk+-2.0 >= 2.12 gthread-2.0 glib-2.0, HAVE_GTK=yes, HAVE_GTK=no)
else
    HAVE_GTK=no
fi

if test "x$enable_alsa" != "xno" ; then
    PKG_CHECK_MODULES(ALSA_DEPS, alsa, HAVE_ALSA=yes, HAVE_ALSA=no)
fi

if test "x$enable_ffmpeg" != "xno" ; then
    PKG_CHECK_MODULES(FFMPEG_DEPS, libavcodec >= 51.0.0 libavutil libavformat >= 52.0.0, HAVE_FFMPEG=yes, HAVE_FFMPEG=no)
fi

if test "x$enable_pulse" != "xno" ; then
    PKG_CHECK_MODULES(PULSE_DEPS, libpulse-simple, HAVE_PULSE=yes, HAVE_PULSE=no)
fi

AC_CHECK_LIB([pthread], [main])
AC_CHECK_LIB([dl], [main])

AC_CHECK_HEADER([iconv.h],[],[iconv.h not found.])

AC_CHECK_LIB([iconv], [main], [have_iconv=yes], [have_iconv=no])
if test "x${have_iconv}" = "xyes" ; then
ICONV_LIB="-liconv"
    AC_SUBST(ICONV_LIB)
    AC_DEFINE(HAVE_LIBICONV,1,[Use libiconv instead of glibc iconv])
fi

AX_CHECK_COMPILER_FLAGS(-msse2, HAVE_SSE2=1, [])
if test ${HAVE_SSE2}; then
    AC_DEFINE(HAVE_SSE2,1,[Support SSE2 instructions])
fi

dnl curl lib
AC_CHECK_LIB([curl], [main], [HAVE_CURL=yes])
AM_CONDITIONAL(HAVE_CURL, test "x$HAVE_CURL" = "xyes")
if test "x$HAVE_CURL" = "xyes"; then
    CURL_LIBS="-lcurl"
    AC_SUBST(CURL_LIBS)
fi

dnl lastfm plugin
if test "x$HAVE_CURL" = "xyes" && test "x$enable_lastfm" != "xno" ; then
    PLUGINS_DIRS="$PLUGINS_DIRS plugins/lastfm"
fi

dnl mpgmad plugin
if test "x$enable_mpgmad" != "xno" ; then
    AC_CHECK_LIB([mad], [main], [HAVE_LIBMAD=yes])
    AM_CONDITIONAL(HAVE_LIBMAD, test "x$HAVE_LIBMAD"="xyes")
    if test "x$HAVE_LIBMAD"="xyes" ; then
        MAD_LIBS="-lmad"
        AC_SUBST(MAD_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/mpgmad"
    fi
fi

dnl vorbis plugin
if test "x$enable_vorbis" != "xno" ; then
    AC_CHECK_LIB([vorbis], [main], [HAVE_VORBIS=yes])
    AC_CHECK_LIB([vorbisfile], [main], [HAVE_VORBISFILE=yes])
    AM_CONDITIONAL(HAVE_VORBIS, test "x$HAVE_VORBIS" = "xyes")
    AM_CONDITIONAL(HAVE_VORBISFILE, test "x$HAVE_VORBISFILE" = "xyes")
    if test "x$HAVE_VORBIS" = "xyes" && test "x$HAVE_VORBISFILE" = "xyes" ; then
        HAVE_VORBISPLUGIN=yes
        VORBIS_LIBS="-lvorbis -lvorbisfile"
        AC_SUBST(VORBIS_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/vorbis"
    fi
fi

dnl flac plugin
if test "x$enable_flac" != "xno" ; then
    AC_CHECK_LIB([FLAC], [main], [HAVE_FLAC=yes])
    AM_CONDITIONAL(HAVE_FLAC, test "x$HAVE_FLAC" = "xyes")
    if test "x$HAVE_FLAC" = "xyes" ; then
        HAVE_FLACPLUGIN=yes
        FLAC_LIBS="-lFLAC"
        AC_SUBST(FLAC_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/flac"
    fi
fi

dnl wavpack plugin
if test "x$enable_wavpack" != "xno" ; then
    AC_CHECK_LIB([wavpack], [main], [HAVE_WAVPACK=yes])
    AM_CONDITIONAL(HAVE_WAVPACK, test "x$HAVE_WAVPACK" = "xyes")
    if test "x$HAVE_WAVPACK" = "xyes" ; then
        HAVE_WAVPACKPLUGIN=yes
        WAVPACK_LIBS="-lwavpack"
        AC_SUBST(WAVPACK_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/wavpack"
    fi
fi

dnl libsndfile plugin
if test "x$enable_sndfile" != "xno" ; then
    AC_CHECK_LIB([sndfile], [main], [HAVE_SNDFILE=yes])
    AM_CONDITIONAL(HAVE_SNDFILE, test "x$HAVE_SNDFILE" = "xyes")
    if test "x$HAVE_SNDFILE" = "xyes" ; then
        HAVE_SNDFILEPLUGIN=yes
        SNDFILE_LIBS="-lsndfile"
        AC_SUBST(SNDFILE_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/sndfile"
    fi
fi

dnl vfs_curl plugin
if test "x$enable_vfs_curl" != "xno" ; then
    if test "x$HAVE_CURL" = "xyes" ; then
        HAVE_VFS_CURL=yes
        VFS_CURL_LIBS="-lcurl"
        AC_SUBST(VFS_CURL_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/vfs_curl"
    fi
fi

dnl faad2 plugin
dnl AC_CHECK_LIB([faad], [main], [HAVE_FAAD=1])
dnl AC_CHECK_LIB([mp4ff], [main], [HAVE_MP4FF=1])
dnl AM_CONDITIONAL(HAVE_FAAD, test $HAVE_FAAD)
dnl AM_CONDITIONAL(HAVE_MP4FF, test $HAVE_MP4FF)
dnl if test ${HAVE_FAAD} && test ${HAVE_MP4FF} ; then
dnl     FAAD2_LIBS="-lfaad -lmp4ff -lmp4v2"
dnl     FAAD2_DIR="plugins/faad2"
dnl     AC_SUBST(FAAD2_LIBS)
dnl     AC_SUBST(FAAD2_DIR)
dnl fi

dnl cdda plugin
if test "x$enable_cdda" != "xno" ; then
    AC_CHECK_LIB([cdio], [main], [HAVE_CDIO=yes])
    AC_CHECK_LIB([cddb], [main], [HAVE_CDDB=yes])
    AM_CONDITIONAL(HAVE_CDIO, test "x$HAVE_CDIO" = "xyes")
    AM_CONDITIONAL(HAVE_CDDB, test "x$HAVE_CDDB" = "xyes")
    if test "x$HAVE_CDIO" = "xyes" && test "x$HAVE_CDDB" = "xyes" ; then
        HAVE_CDDAPLUGIN=yes
        CDDA_LIBS="-lcdio -lcddb"
        AC_SUBST(CDDA_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/cdda"
    fi
fi

dnl gtkui plugin
if test "x$enable_gtkui" != "xno" ; then
    if test "x$HAVE_GTK" = "xyes" ; then
        AC_SUBST(GTKUI_DEPS_CFLAGS)
        AC_SUBST(GTKUI_DEPS_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/gtkui"
    fi
fi
AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")

if test "x$enable_alsa" != "xno" ; then
    if test "x$HAVE_ALSA" = "xyes" ; then
        AC_SUBST(ALSA_DEPS_CFLAGS)
        AC_SUBST(ALSA_DEPS_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/alsa"
    fi
fi
AM_CONDITIONAL(HAVE_ALSA, test "x$HAVE_ALSA" = "xyes")

if test "x$enable_ffmpeg" != "xno" ; then
    AM_CONDITIONAL(HAVE_FFMPEG, test "x$HAVE_FFMPEG" = "xyes")
    if test "x$HAVE_FFMPEG" = "xyes" ; then
        HAVE_FFMPEGPLUGIN=yes
        AC_CHECK_HEADER([ffmpeg/avformat.h], FFMPEG_DEPS_CFLAGS="$FFMPEG_DEPS_CFLAGS -D FFMPEG_OLD")
        AC_SUBST(FFMPEG_DEPS_CFLAGS)
        AC_SUBST(FFMPEG_DEPS_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/ffmpeg"
    fi
fi

AM_CONDITIONAL(HAVE_NOTIFY, test $HAVE_NOTIFY)
if test ${HAVE_NOTIFY}; then
    AC_DEFINE(HAVE_NOTIFY,1,[Use libnotify])
    AC_SUBST(NOTIFY_DEPS_CFLAGS)
    AC_SUBST(NOTIFY_DEPS_LIBS)
fi

if test "x$enable_hotkeys" != "xno" ; then
    AC_CHECK_HEADER([X11/Xlib.h], HAVE_XLIB_H=yes)
    if test "x$HAVE_XLIB_H" = "xyes" ; then
        HOTKEYS_LIBS="-lX11"
        AC_SUBST(HOTKES_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/hotkeys"
    fi
fi

dnl *** OSS output (partly stolen from audacious)
if test "x$enable_oss" != "xno"; then
    have_oss=no

    AC_MSG_CHECKING(for OSS include dir)
    OSS_CFLAGS=""
    if test -f "/etc/oss.conf" ; then
        for i in `cat /etc/oss.conf`; do
            t=`echo $i | sed -e 's/OSSLIBDIR=//'`
            if test "x$i" != "x$t" ; then
                if test -f "$t/include/sys/soundcard.h" -o -f "$i/include/soundcard.h" ; then
                    OSS_CFLAGS="-I$t/include/sys"
                    AC_MSG_RESULT([$OSS_CFLAGS])
                    have_oss=yes
                fi
            fi
        done
    else
        AC_MSG_RESULT([not found])
    fi

    if test "x$have_oss" != "xyes"; then
        AC_MSG_CHECKING(for sys/soundcard.h)
        AC_CHECK_HEADERS(sys/soundcard.h)
        if test "x${ac_cv_header_sys_soundcard_h}" = "xyes" ; then
            have_oss=yes
            AC_MSG_RESULT([found])
        else
            AC_MSG_RESULT([not found])
        fi
    fi


    if test "x$have_oss" = "xyes"; then
        AC_SUBST(OSS_CFLAGS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/oss"
    fi
fi

if test "x$enable_pulseaudio" != "xno"; then
    AM_CONDITIONAL(HAVE_PULSE, test "x$HAVE_PULSE" = "xyes")
    if test "x$HAVE_PULSE" = "xyes"; then
        HAVE_PULSEPLUGIN=yes
        AC_SUBST(PULSE_DEPS_CFLAGS)
        AC_SUBST(PULSE_DEPS_LIBS)
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/pulse"
    fi
fi

if test "x$enable_artwork" != "xno" ; then
    if test "x$HAVE_CURL" = "xyes" && test "x$HAVE_VFS_CURL" = "xyes" ; then
        HAVE_ARTWORK=yes
        PLUGINS_DIRS="$PLUGINS_DIRS plugins/artwork"
    fi
fi

if test "x$enable_adplug" != "xno" ; then
    HAVE_ADPLUG=yes
    PLUGINS_DIRS="$PLUGINS_DIRS plugins/adplug"
fi

if test "x$enable_ffap" != "xno" ; then
    HAVE_FFAP=yes
    PLUGINS_DIRS="$PLUGINS_DIRS plugins/ffap"
fi

if test "x$enable_sid" != "xno" ; then
    HAVE_SID=yes
    PLUGINS_DIRS="$PLUGINS_DIRS plugins/sid"
fi

if test "x$enable_nullout" != "xno" ; then
    HAVE_NULLOUT=yes
    PLUGINS_DIRS="$PLUGINS_DIRS plugins/nullout"
fi

if test "x$enable_supereq" != "xno" ; then
    HAVE_SUPEREQ=yes
    PLUGINS_DIRS="$PLUGINS_DIRS plugins/supereq"
fi

if test "x$enable_vtx" != "xno" ; then
    HAVE_VTX=yes
    PLUGINS_DIRS="$PLUGINS_DIRS plugins/vtx"
fi

AC_SUBST(PLUGINS_DIRS)

echo
echo "Build Configuration:"
echo
echo "* Maintainer Mode:        $USE_MAINTAINER_MODE"
if test "x$USE_MAINTAINER_MODE" = "xyes" ; then
echo "    * Vala:               $VALAC"
fi

dnl print summary
echo
echo "plugin summary:"
echo

AC_DEFUN([PRINT_PLUGIN_INFO],
    [
        if $3 ; then
            echo "    $1: yes - $2"
        else
            echo "    $1: no - $2"
        fi
    ]
)

PRINT_PLUGIN_INFO([stdio],[Standard IO plugin],[true])
PRINT_PLUGIN_INFO([gme],[chiptune music player based on GME],[true])
PRINT_PLUGIN_INFO([dumb],[module player based on DUMB library],[true])
PRINT_PLUGIN_INFO([nullout],[NULL output],[test "x$HAVE_NULLOUT" = "xyes"])
PRINT_PLUGIN_INFO([alsa],[ALSA output],[test "x$HAVE_ALSA" = "xyes"])
PRINT_PLUGIN_INFO([sid],[SID player based on libsidplay2],[test "x$HAVE_SID" = "xyes"])
PRINT_PLUGIN_INFO([ffap],[Monkey's audio (APE) decoder],[test "x$HAVE_FFAP" = "xyes"])
PRINT_PLUGIN_INFO([lastfm],[last.fm scrobbler],[test "x$HAVE_CURL" = "xyes"])
PRINT_PLUGIN_INFO([mpgmad],[mpeg player based on libmad],[test "x$HAVE_LIBMAD" = "xyes"])
PRINT_PLUGIN_INFO([vorbis],[ogg vorbis player],[test "x$HAVE_VORBISPLUGIN" = "xyes"])
PRINT_PLUGIN_INFO([flac],[flac player],[test "x$HAVE_FLACPLUGIN" = "xyes"])
PRINT_PLUGIN_INFO([wavpack],[wavpack player],[test "x$HAVE_WAVPACKPLUGIN" = "xyes"])
PRINT_PLUGIN_INFO([sndfile],[PCM (wav,aiff,etc) player based on libsndfile],[test "x$HAVE_SNDFILEPLUGIN" = "xyes"])
PRINT_PLUGIN_INFO([vtx],[vtx file player (ay8910/12 emulation)],[test "x$HAVE_VTX" = "xyes"])
PRINT_PLUGIN_INFO([adplug],[adplug player (OPL2/OPL3 emulation)],[test "x$HAVE_ADPLUG" = "xyes"])
PRINT_PLUGIN_INFO([vfs_curl],[http/ftp streaming support],[test "x$HAVE_VFS_CURL" = "xyes"])
dnl PRINT_PLUGIN_INFO([faad2],[aac/mp4 player],[test $HAVE_FAAD && test $HAVE_MP4FF])
PRINT_PLUGIN_INFO([cdda],[cd audio player],[test "x$HAVE_CDDAPLUGIN" = "xyes"])
PRINT_PLUGIN_INFO([gtkui],[GTK user interface],[test "x$HAVE_GTK" = "xyes"])
PRINT_PLUGIN_INFO([hotkeys],[Global hotkeys support],[test "x$HAVE_XLIB_H" = "xyes"])
PRINT_PLUGIN_INFO([libnotify],[Current track notification],[test "x$HAVE_NOTIFY" = "xyes"])
PRINT_PLUGIN_INFO([ffmpeg],[ffmpeg codecs],[test "x$HAVE_FFMPEGPLUGIN" = "xyes"])
PRINT_PLUGIN_INFO([oss],[oss output plugin],[test "x$have_oss" = "xyes"])
PRINT_PLUGIN_INFO([pulse],[PulseAudio output plugin],[test "x$HAVE_PULSEPLUGIN" = "xyes"])
PRINT_PLUGIN_INFO([artwork],[Cover art plugin],[test "x$HAVE_ARTWORK" = "xyes"])
PRINT_PLUGIN_INFO([supereq],[Equalizer based on Super EQ library by Naoki Shibata],[test "x$HAVE_SUPEREQ" = "xyes"])
echo
echo "plugin build directories: $PLUGINS_DIRS"

echo

AC_OUTPUT([
Makefile
pixmaps/Makefile
icons/Makefile
gme/Game_Music_Emu-0.5.2/Makefile
gme/Game_Music_Emu-0.5.2/gme/Makefile
plugins/sid/sidplay-libs/Makefile
dumb/Makefile
plugins/alsa/Makefile
plugins/hotkeys/Makefile
plugins/lastfm/Makefile
plugins/ffap/Makefile
plugins/mpgmad/Makefile
plugins/vorbis/Makefile
plugins/flac/Makefile
plugins/wavpack/Makefile
plugins/sndfile/Makefile
plugins/vfs_curl/Makefile
plugins/cdda/Makefile
plugins/gtkui/Makefile
plugins/nullout/Makefile
plugins/vtx/Makefile
plugins/adplug/Makefile
plugins/ffmpeg/Makefile
plugins/sid/Makefile
plugins/oss/Makefile
plugins/pulse/Makefile
plugins/artwork/Makefile
plugins/supereq/Makefile
deadbeef.desktop
])