1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
|
(* *********************************************************************)
(* *)
(* The Compcert verified compiler *)
(* *)
(* Xavier Leroy, INRIA Paris-Rocquencourt *)
(* *)
(* Copyright Institut National de Recherche en Informatique et en *)
(* Automatique. All rights reserved. This file is distributed *)
(* under the terms of the INRIA Non-Commercial License Agreement. *)
(* *)
(* *********************************************************************)
(** Strength reduction for operators and conditions.
This is the machine-dependent part of [Constprop]. *)
Require Import Coqlib.
Require Import Compopts.
Require Import AST.
Require Import Integers.
Require Import Floats.
Require Import Op.
Require Import Registers.
Require Import ValueDomain.
(** * Operator strength reduction *)
(** We now define auxiliary functions for strength reduction of
operators and addressing modes: replacing an operator with a cheaper
one if some of its arguments are statically known. These are again
large pattern-matchings expressed in indirect style. *)
Nondetfunction cond_strength_reduction
(cond: condition) (args: list reg) (vl: list aval) :=
match cond, args, vl with
| Ccomp c, r1 :: r2 :: nil, I n1 :: v2 :: nil =>
(Ccompimm (swap_comparison c) n1, r2 :: nil)
| Ccomp c, r1 :: r2 :: nil, v1 :: I n2 :: nil =>
(Ccompimm c n2, r1 :: nil)
| Ccompu c, r1 :: r2 :: nil, I n1 :: v2 :: nil =>
(Ccompuimm (swap_comparison c) n1, r2 :: nil)
| Ccompu c, r1 :: r2 :: nil, v1 :: I n2 :: nil =>
(Ccompuimm c n2, r1 :: nil)
| _, _, _ =>
(cond, args)
end.
Nondetfunction addr_strength_reduction
(addr: addressing) (args: list reg) (vl: list aval) :=
match addr, args, vl with
| Aindexed ofs, r1 :: nil, Ptr(Gl symb n) :: nil =>
(Aglobal symb (Int.add n ofs), nil)
| Aindexed ofs, r1 :: nil, Ptr(Stk n) :: nil =>
(Ainstack (Int.add n ofs), nil)
| Aindexed2 ofs, r1 :: r2 :: nil, Ptr(Gl symb n1) :: I n2 :: nil =>
(Aglobal symb (Int.add (Int.add n1 n2) ofs), nil)
| Aindexed2 ofs, r1 :: r2 :: nil, I n1 :: Ptr(Gl symb n2) :: nil =>
(Aglobal symb (Int.add (Int.add n1 n2) ofs), nil)
| Aindexed2 ofs, r1 :: r2 :: nil, Ptr(Stk n1) :: I n2 :: nil =>
(Ainstack (Int.add (Int.add n1 n2) ofs), nil)
| Aindexed2 ofs, r1 :: r2 :: nil, I n1 :: Ptr(Stk n2) :: nil =>
(Ainstack (Int.add (Int.add n1 n2) ofs), nil)
| Aindexed2 ofs, r1 :: r2 :: nil, Ptr(Gl symb n1) :: v2 :: nil =>
(Abased symb (Int.add n1 ofs), r2 :: nil)
| Aindexed2 ofs, r1 :: r2 :: nil, v1 :: Ptr(Gl symb n2) :: nil =>
(Abased symb (Int.add n2 ofs), r1 :: nil)
| Aindexed2 ofs, r1 :: r2 :: nil, I n1 :: v2 :: nil =>
(Aindexed (Int.add n1 ofs), r2 :: nil)
| Aindexed2 ofs, r1 :: r2 :: nil, v1 :: I n2 :: nil =>
(Aindexed (Int.add n2 ofs), r1 :: nil)
| Aindexed2scaled sc ofs, r1 :: r2 :: nil, Ptr(Gl symb n1) :: I n2 :: nil =>
(Aglobal symb (Int.add (Int.add n1 (Int.mul n2 sc)) ofs), nil)
| Aindexed2scaled sc ofs, r1 :: r2 :: nil, Ptr(Gl symb n1) :: v2 :: nil =>
(Abasedscaled sc symb (Int.add n1 ofs), r2 :: nil)
| Aindexed2scaled sc ofs, r1 :: r2 :: nil, v1 :: I n2 :: nil =>
(Aindexed (Int.add (Int.mul n2 sc) ofs), r1 :: nil)
| Abased id ofs, r1 :: nil, I n1 :: nil =>
(Aglobal id (Int.add ofs n1), nil)
| Abasedscaled sc id ofs, r1 :: nil, I n1 :: nil =>
(Aglobal id (Int.add ofs (Int.mul sc n1)), nil)
| _, _ =>
(addr, args)
end.
Definition make_addimm (n: int) (r: reg) :=
if Int.eq n Int.zero
then (Omove, r :: nil)
else (Olea (Aindexed n), r :: nil).
Definition make_shlimm (n: int) (r: reg) :=
if Int.eq n Int.zero
then (Omove, r :: nil)
else (Oshlimm n, r :: nil).
Definition make_shrimm (n: int) (r: reg) :=
if Int.eq n Int.zero
then (Omove, r :: nil)
else (Oshrimm n, r :: nil).
Definition make_shruimm (n: int) (r: reg) :=
if Int.eq n Int.zero
then (Omove, r :: nil)
else (Oshruimm n, r :: nil).
Definition make_mulimm (n: int) (r: reg) :=
if Int.eq n Int.zero then
(Ointconst Int.zero, nil)
else if Int.eq n Int.one then
(Omove, r :: nil)
else
match Int.is_power2 n with
| Some l => make_shlimm l r
| None => (Omulimm n, r :: nil)
end.
Definition make_andimm (n: int) (r: reg) (a: aval) :=
if Int.eq n Int.zero then (Ointconst Int.zero, nil)
else if Int.eq n Int.mone then (Omove, r :: nil)
else if match a with Uns m => Int.eq (Int.zero_ext m (Int.not n)) Int.zero
| _ => false end
then (Omove, r :: nil)
else (Oandimm n, r :: nil).
Definition make_orimm (n: int) (r: reg) :=
if Int.eq n Int.zero then (Omove, r :: nil)
else if Int.eq n Int.mone then (Ointconst Int.mone, nil)
else (Oorimm n, r :: nil).
Definition make_xorimm (n: int) (r: reg) :=
if Int.eq n Int.zero
then (Omove, r :: nil)
else (Oxorimm n, r :: nil).
Definition make_divimm n (r1 r2: reg) :=
match Int.is_power2 n with
| Some l => if Int.ltu l (Int.repr 31)
then (Oshrximm l, r1 :: nil)
else (Odiv, r1 :: r2 :: nil)
| None => (Odiv, r1 :: r2 :: nil)
end.
Definition make_divuimm n (r1 r2: reg) :=
match Int.is_power2 n with
| Some l => make_shruimm l r1
| None => (Odivu, r1 :: r2 :: nil)
end.
Definition make_moduimm n (r1 r2: reg) :=
match Int.is_power2 n with
| Some l => (Oandimm (Int.sub n Int.one), r1 :: nil)
| None => (Omodu, r1 :: r2 :: nil)
end.
Definition make_mulfimm (n: float) (r r1 r2: reg) :=
if Float.eq_dec n (Float.floatofint (Int.repr 2))
then (Oaddf, r :: r :: nil)
else (Omulf, r1 :: r2 :: nil).
Definition make_cast8signed (r: reg) (a: aval) :=
if vincl a (Sgn 8) then (Omove, r :: nil) else (Ocast8signed, r :: nil).
Definition make_cast8unsigned (r: reg) (a: aval) :=
if vincl a (Uns 8) then (Omove, r :: nil) else (Ocast8unsigned, r :: nil).
Definition make_cast16signed (r: reg) (a: aval) :=
if vincl a (Sgn 16) then (Omove, r :: nil) else (Ocast16signed, r :: nil).
Definition make_cast16unsigned (r: reg) (a: aval) :=
if vincl a (Uns 16) then (Omove, r :: nil) else (Ocast16unsigned, r :: nil).
Definition make_singleoffloat (r: reg) (a: aval) :=
if vincl a Fsingle && generate_float_constants tt
then (Omove, r :: nil)
else (Osingleoffloat, r :: nil).
Nondetfunction op_strength_reduction
(op: operation) (args: list reg) (vl: list aval) :=
match op, args, vl with
| Ocast8signed, r1 :: nil, v1 :: nil => make_cast8signed r1 v1
| Ocast8unsigned, r1 :: nil, v1 :: nil => make_cast8unsigned r1 v1
| Ocast16signed, r1 :: nil, v1 :: nil => make_cast16signed r1 v1
| Ocast16unsigned, r1 :: nil, v1 :: nil => make_cast16unsigned r1 v1
| Osub, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_addimm (Int.neg n2) r1
| Omul, r1 :: r2 :: nil, I n1 :: v2 :: nil => make_mulimm n1 r2
| Omul, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_mulimm n2 r1
| Odiv, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_divimm n2 r1 r2
| Odivu, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_divuimm n2 r1 r2
| Omodu, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_moduimm n2 r1 r2
| Oand, r1 :: r2 :: nil, I n1 :: v2 :: nil => make_andimm n1 r2 v2
| Oand, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_andimm n2 r1 v1
| Oandimm n, r1 :: nil, v1 :: nil => make_andimm n r1 v1
| Oor, r1 :: r2 :: nil, I n1 :: v2 :: nil => make_orimm n1 r2
| Oor, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_orimm n2 r1
| Oxor, r1 :: r2 :: nil, I n1 :: v2 :: nil => make_xorimm n1 r2
| Oxor, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_xorimm n2 r1
| Oshl, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_shlimm n2 r1
| Oshr, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_shrimm n2 r1
| Oshru, r1 :: r2 :: nil, v1 :: I n2 :: nil => make_shruimm n2 r1
| Olea addr, args, vl =>
let (addr', args') := addr_strength_reduction addr args vl in
(Olea addr', args')
| Osingleoffloat, r1 :: nil, v1 :: nil => make_singleoffloat r1 v1
| Ocmp c, args, vl =>
let (c', args') := cond_strength_reduction c args vl in
(Ocmp c', args')
| Omulf, r1 :: r2 :: nil, v1 :: F n2 :: nil => make_mulfimm n2 r1 r1 r2
| Omulf, r1 :: r2 :: nil, F n1 :: v2 :: nil => make_mulfimm n1 r2 r1 r2
| _, _, _ => (op, args)
end.
|
