From 87d88ebbe2b325f8b172af6f519a1070d94f39cb Mon Sep 17 00:00:00 2001
From: Gil <mcg@google.com>
Date: Tue, 12 Dec 2017 11:13:02 -0800
Subject: Add leveldb to the Firestore cmake build (#559)

* Use Debug as the default build type if unspecified

* Add a leveldb ExternalProject, FindLevelDB module, and use it in Firestore

* Accept an externally built leveldb via LEVELDB_ROOT

* Clone leveldb via https: instead of git:

* Remove extra DOWNLOAD_DIR which doesn't work with GIT sources
---
 cmake/FindLevelDB.cmake        | 55 +++++++++++++++++++++++++++++++++++
 cmake/external/firestore.cmake |  2 +-
 cmake/external/leveldb.cmake   | 65 ++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 121 insertions(+), 1 deletion(-)
 create mode 100644 cmake/FindLevelDB.cmake
 create mode 100644 cmake/external/leveldb.cmake

(limited to 'cmake')

diff --git a/cmake/FindLevelDB.cmake b/cmake/FindLevelDB.cmake
new file mode 100644
index 0000000..ae32a17
--- /dev/null
+++ b/cmake/FindLevelDB.cmake
@@ -0,0 +1,55 @@
+# Copyright 2017 Google
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+set(binary_dir ${FIREBASE_BINARY_DIR}/third_party/leveldb/src/leveldb)
+
+find_path(
+  LEVELDB_INCLUDE_DIR leveldb/db.h
+  HINTS
+    $ENV{LEVELDB_ROOT}/include
+    ${LEVELDB_ROOT}/include
+    ${binary_dir}/include
+  PATH_SUFFIXES leveldb
+)
+
+find_library(
+  LEVELDB_LIBRARY
+  NAMES leveldb
+  HINTS
+    $ENV{LEVELDB_ROOT}/lib
+    ${LEVELDB_ROOT}/lib
+    ${binary_dir}/out-static
+)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(
+  LevelDB
+  DEFAULT_MSG
+  LEVELDB_INCLUDE_DIR
+  LEVELDB_LIBRARY
+)
+
+if(LEVELDB_FOUND)
+  set(LEVELDB_INCLUDE_DIRS ${LEVELDB_INCLUDE_DIR})
+  set(LEVELDB_LIBRARIES ${LEVELDB_LIBRARY})
+
+  if (NOT TARGET LevelDB::LevelDB)
+    add_library(LevelDB::LevelDB UNKNOWN IMPORTED)
+    set_target_properties(
+      LevelDB::LevelDB PROPERTIES
+      INTERFACE_INCLUDE_DIRECTORIES ${LEVELDB_INCLUDE_DIR}
+      IMPORTED_LOCATION ${LEVELDB_LIBRARY}
+    )
+  endif()
+endif(LEVELDB_FOUND)
diff --git a/cmake/external/firestore.cmake b/cmake/external/firestore.cmake
index dd37b51..9fb673e 100644
--- a/cmake/external/firestore.cmake
+++ b/cmake/external/firestore.cmake
@@ -19,7 +19,7 @@ set(binary_dir ${PROJECT_BINARY_DIR}/Firestore)
 
 ExternalProject_Add(
   Firestore
-  DEPENDS googletest abseil-cpp
+  DEPENDS abseil-cpp googletest leveldb
 
   # Lay the binary directory out as if this were a subproject. This makes it
   # possible to build and test in it directly.
diff --git a/cmake/external/leveldb.cmake b/cmake/external/leveldb.cmake
new file mode 100644
index 0000000..9b4d390
--- /dev/null
+++ b/cmake/external/leveldb.cmake
@@ -0,0 +1,65 @@
+# Copyright 2017 Google
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+include(ExternalProject)
+
+if(LEVELDB_ROOT)
+  # If the user has supplied a LEVELDB_ROOT then just use it. Add an empty
+  # custom target so that the superbuild depdendencies don't all have to be
+  # conditional.
+  add_custom_target(leveldb)
+
+else()
+  # LevelDB does not build on Windows (yet)
+  # See:
+  #   https://github.com/google/leveldb/issues/363
+  #   https://github.com/google/leveldb/issues/466
+  if(NOT WIN32)
+    # Clean up warning output to reduce noise in the build
+    if(CMAKE_CXX_COMPILER_ID MATCHES "Clang|GNU")
+      set(
+        LEVELDB_CXX_FLAGS "\
+          -Wno-deprecated-declarations"
+      )
+    endif()
+
+    # Map CMake compiler configuration down onto the leveldb Makefile
+    set(
+      LEVELDB_OPT "\
+        $<$<CONFIG:Debug>:${CMAKE_CXX_FLAGS_DEBUG}> \
+        $<$<CONFIG:Release>:${CMAKE_CXX_FLAGS_RELEASE}>"
+    )
+
+    ExternalProject_Add(
+      leveldb
+
+      GIT_REPOSITORY "https://github.com/google/leveldb.git"
+      GIT_TAG "v1.20"
+
+      PREFIX ${PROJECT_BINARY_DIR}/third_party/leveldb
+
+      CONFIGURE_COMMAND ""
+      BUILD_ALWAYS ON
+      BUILD_IN_SOURCE ON
+      BUILD_COMMAND
+        env CXXFLAGS=${LEVELDB_CXX_FLAGS} OPT=${LEVELDB_OPT} make -j all
+
+      INSTALL_DIR ${FIREBASE_INSTALL_DIR}
+
+      INSTALL_COMMAND ""
+      TEST_COMMAND ""
+    )
+
+  endif(NOT WIN32)
+endif(LEVELDB_ROOT)
-- 
cgit v1.2.3