1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
|
(************************************************************************)
(* v * The Coq Proof Assistant / The Coq Development Team *)
(* <O___,, * CNRS-Ecole Polytechnique-INRIA Futurs-Universite Paris Sud *)
(* \VV/ **************************************************************)
(* // * This file is distributed under the terms of the *)
(* * GNU Lesser General Public License Version 2.1 *)
(************************************************************************)
(*i $Id$ i*)
Require Import ZArith.
Require Import Nnat.
Require Import NAxioms.
Require Import NSig.
(** * The interface [NSig.NType] implies the interface [NAxiomsSig] *)
Module NSig_NAxioms (N:NType) <: NAxiomsSig.
Delimit Scope NumScope with Num.
Bind Scope NumScope with N.t.
Local Open Scope NumScope.
Local Notation "[ x ]" := (N.to_Z x) : NumScope.
Local Infix "==" := N.eq (at level 70) : NumScope.
Local Notation "0" := N.zero : NumScope.
Local Infix "+" := N.add : NumScope.
Local Infix "-" := N.sub : NumScope.
Local Infix "*" := N.mul : NumScope.
Hint Rewrite
N.spec_0 N.spec_succ N.spec_add N.spec_mul N.spec_pred N.spec_sub : num.
Ltac nsimpl := autorewrite with num.
Ltac ncongruence := unfold N.eq; repeat red; intros; nsimpl; congruence.
Obligation Tactic := ncongruence.
Instance: @Measure N.t Z N.to_Z.
Instance eq_equiv : Equivalence N.eq.
Program Instance succ_wd : Proper (N.eq==>N.eq) N.succ.
Program Instance pred_wd : Proper (N.eq==>N.eq) N.pred.
Program Instance add_wd : Proper (N.eq==>N.eq==>N.eq) N.add.
Program Instance sub_wd : Proper (N.eq==>N.eq==>N.eq) N.sub.
Program Instance mul_wd : Proper (N.eq==>N.eq==>N.eq) N.mul.
Theorem pred_succ : forall n, N.pred (N.succ n) == n.
Proof.
unfold N.eq; repeat red; intros.
rewrite N.spec_pred; rewrite N.spec_succ.
generalize (N.spec_pos n); omega with *.
Qed.
Definition N_of_Z z := N.of_N (Zabs_N z).
Section Induction.
Variable A : N.t -> Prop.
Hypothesis A_wd : Proper (N.eq==>iff) A.
Hypothesis A0 : A 0.
Hypothesis AS : forall n, A n <-> A (N.succ n).
Let B (z : Z) := A (N_of_Z z).
Lemma B0 : B 0.
Proof.
unfold B, N_of_Z; simpl.
rewrite <- (A_wd 0); auto.
red; rewrite N.spec_0, N.spec_of_N; auto.
Qed.
Lemma BS : forall z : Z, (0 <= z)%Z -> B z -> B (z + 1).
Proof.
intros z H1 H2.
unfold B in *. apply -> AS in H2.
setoid_replace (N_of_Z (z + 1)) with (N.succ (N_of_Z z)); auto.
unfold N.eq. rewrite N.spec_succ.
unfold N_of_Z.
rewrite 2 N.spec_of_N, 2 Z_of_N_abs, 2 Zabs_eq; auto with zarith.
Qed.
Lemma B_holds : forall z : Z, (0 <= z)%Z -> B z.
Proof.
exact (natlike_ind B B0 BS).
Qed.
Theorem bi_induction : forall n, A n.
Proof.
intro n. setoid_replace n with (N_of_Z (N.to_Z n)).
apply B_holds. apply N.spec_pos.
red; unfold N_of_Z.
rewrite N.spec_of_N, Z_of_N_abs, Zabs_eq; auto.
apply N.spec_pos.
Qed.
End Induction.
Theorem add_0_l : forall n, 0 + n == n.
Proof.
intros; red; nsimpl; auto with zarith.
Qed.
Theorem add_succ_l : forall n m, (N.succ n) + m == N.succ (n + m).
Proof.
intros; red; nsimpl; auto with zarith.
Qed.
Theorem sub_0_r : forall n, n - 0 == n.
Proof.
intros; red; nsimpl. generalize (N.spec_pos n); omega with *.
Qed.
Theorem sub_succ_r : forall n m, n - (N.succ m) == N.pred (n - m).
Proof.
intros; red; nsimpl. omega with *.
Qed.
Theorem mul_0_l : forall n, 0 * n == 0.
Proof.
intros; red; nsimpl; auto with zarith.
Qed.
Theorem mul_succ_l : forall n m, (N.succ n) * m == n * m + m.
Proof.
intros; red; nsimpl. ring.
Qed.
(** Order *)
Infix "<=" := N.le : NumScope.
Infix "<" := N.lt : NumScope.
Lemma spec_compare_alt : forall x y, N.compare x y = ([x] ?= [y])%Z.
Proof.
intros; generalize (N.spec_compare x y).
destruct (N.compare x y); auto.
intros H; rewrite H; symmetry; apply Zcompare_refl.
Qed.
Lemma spec_lt : forall x y, (x<y) <-> ([x]<[y])%Z.
Proof.
intros; unfold N.lt, Zlt; rewrite spec_compare_alt; intuition.
Qed.
Lemma spec_le : forall x y, (x<=y) <-> ([x]<=[y])%Z.
Proof.
intros; unfold N.le, Zle; rewrite spec_compare_alt; intuition.
Qed.
Lemma spec_min : forall x y, [N.min x y] = Zmin [x] [y].
Proof.
intros; unfold N.min, Zmin.
rewrite spec_compare_alt; destruct Zcompare; auto.
Qed.
Lemma spec_max : forall x y, [N.max x y] = Zmax [x] [y].
Proof.
intros; unfold N.max, Zmax.
rewrite spec_compare_alt; destruct Zcompare; auto.
Qed.
Instance compare_wd : Proper (N.eq ==> N.eq ==> eq) N.compare.
Proof.
intros x x' Hx y y' Hy.
rewrite 2 spec_compare_alt. unfold N.eq in *. rewrite Hx, Hy; intuition.
Qed.
Instance lt_wd : Proper (N.eq ==> N.eq ==> iff) N.lt.
Proof.
intros x x' Hx y y' Hy; unfold N.lt; rewrite Hx, Hy; intuition.
Qed.
Theorem lt_eq_cases : forall n m, n <= m <-> n < m \/ n == m.
Proof.
intros.
unfold N.eq; rewrite spec_lt, spec_le; omega.
Qed.
Theorem lt_irrefl : forall n, ~ n < n.
Proof.
intros; rewrite spec_lt; auto with zarith.
Qed.
Theorem lt_succ_r : forall n m, n < (N.succ m) <-> n <= m.
Proof.
intros; rewrite spec_lt, spec_le, N.spec_succ; omega.
Qed.
Theorem min_l : forall n m, n <= m -> N.min n m == n.
Proof.
intros n m; red; rewrite spec_le, spec_min; omega with *.
Qed.
Theorem min_r : forall n m, m <= n -> N.min n m == m.
Proof.
intros n m; red; rewrite spec_le, spec_min; omega with *.
Qed.
Theorem max_l : forall n m, m <= n -> N.max n m == n.
Proof.
intros n m; red; rewrite spec_le, spec_max; omega with *.
Qed.
Theorem max_r : forall n m, n <= m -> N.max n m == m.
Proof.
intros n m; red; rewrite spec_le, spec_max; omega with *.
Qed.
(** Properties specific to natural numbers, not integers. *)
Theorem pred_0 : N.pred 0 == 0.
Proof.
red; nsimpl; auto.
Qed.
Definition recursion (A : Type) (a : A) (f : N.t -> A -> A) (n : N.t) :=
Nrect (fun _ => A) a (fun n a => f (N.of_N n) a) (N.to_N n).
Implicit Arguments recursion [A].
Instance recursion_wd (A : Type) (Aeq : relation A) :
Proper (Aeq ==> (N.eq==>Aeq==>Aeq) ==> N.eq ==> Aeq) (@recursion A).
Proof.
unfold N.eq.
intros A Aeq a a' Eaa' f f' Eff' x x' Exx'.
unfold recursion.
unfold N.to_N.
rewrite <- Exx'; clear x' Exx'.
replace (Zabs_N [x]) with (N_of_nat (Zabs_nat [x])).
induction (Zabs_nat [x]).
simpl; auto.
rewrite N_of_S, 2 Nrect_step; auto. apply Eff'; auto.
destruct [x]; simpl; auto.
change (nat_of_P p) with (nat_of_N (Npos p)); apply N_of_nat_of_N.
change (nat_of_P p) with (nat_of_N (Npos p)); apply N_of_nat_of_N.
Qed.
Theorem recursion_0 :
forall (A : Type) (a : A) (f : N.t -> A -> A), recursion a f 0 = a.
Proof.
intros A a f; unfold recursion, N.to_N; rewrite N.spec_0; simpl; auto.
Qed.
Theorem recursion_succ :
forall (A : Type) (Aeq : relation A) (a : A) (f : N.t -> A -> A),
Aeq a a -> Proper (N.eq==>Aeq==>Aeq) f ->
forall n, Aeq (recursion a f (N.succ n)) (f n (recursion a f n)).
Proof.
unfold N.eq, recursion; intros A Aeq a f EAaa f_wd n.
replace (N.to_N (N.succ n)) with (Nsucc (N.to_N n)).
rewrite Nrect_step.
apply f_wd; auto.
unfold N.to_N.
rewrite N.spec_of_N, Z_of_N_abs, Zabs_eq; auto.
apply N.spec_pos.
fold (recursion a f n).
apply recursion_wd; auto.
red; auto.
unfold N.to_N.
rewrite N.spec_succ.
change ([n]+1)%Z with (Zsucc [n]).
apply Z_of_N_eq_rev.
rewrite Z_of_N_succ.
rewrite 2 Z_of_N_abs.
rewrite 2 Zabs_eq; auto.
generalize (N.spec_pos n); auto with zarith.
apply N.spec_pos; auto.
Qed.
(** The instantiation of operations.
Placing them at the very end avoids having indirections in above lemmas. *)
Definition t := N.t.
Definition eq := N.eq.
Definition zero := N.zero.
Definition succ := N.succ.
Definition pred := N.pred.
Definition add := N.add.
Definition sub := N.sub.
Definition mul := N.mul.
Definition lt := N.lt.
Definition le := N.le.
Definition min := N.min.
Definition max := N.max.
End NSig_NAxioms.
|
