1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
|
(************************************************************************)
(* v * The Coq Proof Assistant / The Coq Development Team *)
(* <O___,, * CNRS-Ecole Polytechnique-INRIA Futurs-Universite Paris Sud *)
(* \VV/ **************************************************************)
(* // * This file is distributed under the terms of the *)
(* * GNU Lesser General Public License Version 2.1 *)
(************************************************************************)
(*i $Id$ i*)
Require Import ZArith ZAxioms ZSgnAbs ZSig.
(** * The interface [ZSig.ZType] implies the interface [ZAxiomsSig] *)
Module ZSig_ZAxioms (Z:ZType) <: ZAxiomsExtSig.
Local Notation "[ x ]" := (Z.to_Z x).
Local Infix "==" := Z.eq (at level 70).
Local Notation "0" := Z.zero.
Local Infix "+" := Z.add.
Local Infix "-" := Z.sub.
Local Infix "*" := Z.mul.
Local Notation "- x" := (Z.opp x).
Local Infix "<=" := Z.le.
Local Infix "<" := Z.lt.
Hint Rewrite
Z.spec_0 Z.spec_1 Z.spec_add Z.spec_sub Z.spec_pred Z.spec_succ
Z.spec_mul Z.spec_opp Z.spec_of_Z : zspec.
Ltac zsimpl := unfold Z.eq in *; autorewrite with zspec.
Ltac zcongruence := repeat red; intros; zsimpl; congruence.
Instance eq_equiv : Equivalence Z.eq.
Proof. unfold Z.eq. firstorder. Qed.
Obligation Tactic := zcongruence.
Program Instance succ_wd : Proper (Z.eq ==> Z.eq) Z.succ.
Program Instance pred_wd : Proper (Z.eq ==> Z.eq) Z.pred.
Program Instance add_wd : Proper (Z.eq ==> Z.eq ==> Z.eq) Z.add.
Program Instance sub_wd : Proper (Z.eq ==> Z.eq ==> Z.eq) Z.sub.
Program Instance mul_wd : Proper (Z.eq ==> Z.eq ==> Z.eq) Z.mul.
Theorem pred_succ : forall n, Z.pred (Z.succ n) == n.
Proof.
intros; zsimpl; auto with zarith.
Qed.
Section Induction.
Variable A : Z.t -> Prop.
Hypothesis A_wd : Proper (Z.eq==>iff) A.
Hypothesis A0 : A 0.
Hypothesis AS : forall n, A n <-> A (Z.succ n).
Let B (z : Z) := A (Z.of_Z z).
Lemma B0 : B 0.
Proof.
unfold B; simpl.
rewrite <- (A_wd 0); auto.
zsimpl; auto.
Qed.
Lemma BS : forall z : Z, B z -> B (z + 1).
Proof.
intros z H.
unfold B in *. apply -> AS in H.
setoid_replace (Z.of_Z (z + 1)) with (Z.succ (Z.of_Z z)); auto.
zsimpl; auto.
Qed.
Lemma BP : forall z : Z, B z -> B (z - 1).
Proof.
intros z H.
unfold B in *. rewrite AS.
setoid_replace (Z.succ (Z.of_Z (z - 1))) with (Z.of_Z z); auto.
zsimpl; auto with zarith.
Qed.
Lemma B_holds : forall z : Z, B z.
Proof.
intros; destruct (Z_lt_le_dec 0 z).
apply natlike_ind; auto with zarith.
apply B0.
intros; apply BS; auto.
replace z with (-(-z))%Z in * by (auto with zarith).
remember (-z)%Z as z'.
pattern z'; apply natlike_ind.
apply B0.
intros; rewrite Zopp_succ; unfold Zpred; apply BP; auto.
subst z'; auto with zarith.
Qed.
Theorem bi_induction : forall n, A n.
Proof.
intro n. setoid_replace n with (Z.of_Z (Z.to_Z n)).
apply B_holds.
zsimpl; auto.
Qed.
End Induction.
Theorem add_0_l : forall n, 0 + n == n.
Proof.
intros; zsimpl; auto with zarith.
Qed.
Theorem add_succ_l : forall n m, (Z.succ n) + m == Z.succ (n + m).
Proof.
intros; zsimpl; auto with zarith.
Qed.
Theorem sub_0_r : forall n, n - 0 == n.
Proof.
intros; zsimpl; auto with zarith.
Qed.
Theorem sub_succ_r : forall n m, n - (Z.succ m) == Z.pred (n - m).
Proof.
intros; zsimpl; auto with zarith.
Qed.
Theorem mul_0_l : forall n, 0 * n == 0.
Proof.
intros; zsimpl; auto with zarith.
Qed.
Theorem mul_succ_l : forall n m, (Z.succ n) * m == n * m + m.
Proof.
intros; zsimpl; ring.
Qed.
(** Order *)
Lemma spec_compare_alt : forall x y, Z.compare x y = ([x] ?= [y])%Z.
Proof.
intros; generalize (Z.spec_compare x y).
destruct (Z.compare x y); auto.
intros H; rewrite H; symmetry; apply Zcompare_refl.
Qed.
Lemma spec_lt : forall x y, (x<y) <-> ([x]<[y])%Z.
Proof.
intros; unfold Z.lt, Zlt; rewrite spec_compare_alt; intuition.
Qed.
Lemma spec_le : forall x y, (x<=y) <-> ([x]<=[y])%Z.
Proof.
intros; unfold Z.le, Zle; rewrite spec_compare_alt; intuition.
Qed.
Lemma spec_min : forall x y, [Z.min x y] = Zmin [x] [y].
Proof.
intros; unfold Z.min, Zmin.
rewrite spec_compare_alt; destruct Zcompare; auto.
Qed.
Lemma spec_max : forall x y, [Z.max x y] = Zmax [x] [y].
Proof.
intros; unfold Z.max, Zmax.
rewrite spec_compare_alt; destruct Zcompare; auto.
Qed.
Instance compare_wd : Proper (Z.eq ==> Z.eq ==> eq) Z.compare.
Proof.
intros x x' Hx y y' Hy.
rewrite 2 spec_compare_alt; unfold Z.eq in *; rewrite Hx, Hy; intuition.
Qed.
Instance lt_wd : Proper (Z.eq ==> Z.eq ==> iff) Z.lt.
Proof.
intros x x' Hx y y' Hy; unfold Z.lt; rewrite Hx, Hy; intuition.
Qed.
Theorem lt_eq_cases : forall n m, n <= m <-> n < m \/ n == m.
Proof.
intros.
unfold Z.eq; rewrite spec_lt, spec_le; omega.
Qed.
Theorem lt_irrefl : forall n, ~ n < n.
Proof.
intros; rewrite spec_lt; auto with zarith.
Qed.
Theorem lt_succ_r : forall n m, n < (Z.succ m) <-> n <= m.
Proof.
intros; rewrite spec_lt, spec_le, Z.spec_succ; omega.
Qed.
Theorem min_l : forall n m, n <= m -> Z.min n m == n.
Proof.
intros n m; unfold Z.eq; rewrite spec_le, spec_min.
generalize (Zmin_spec [n] [m]); omega.
Qed.
Theorem min_r : forall n m, m <= n -> Z.min n m == m.
Proof.
intros n m; unfold Z.eq; rewrite spec_le, spec_min.
generalize (Zmin_spec [n] [m]); omega.
Qed.
Theorem max_l : forall n m, m <= n -> Z.max n m == n.
Proof.
intros n m; unfold Z.eq; rewrite spec_le, spec_max.
generalize (Zmax_spec [n] [m]); omega.
Qed.
Theorem max_r : forall n m, n <= m -> Z.max n m == m.
Proof.
intros n m; unfold Z.eq; rewrite spec_le, spec_max.
generalize (Zmax_spec [n] [m]); omega.
Qed.
(** Part specific to integers, not natural numbers *)
Program Instance opp_wd : Proper (Z.eq ==> Z.eq) Z.opp.
Theorem succ_pred : forall n, Z.succ (Z.pred n) == n.
Proof.
red; intros; zsimpl; auto with zarith.
Qed.
Theorem opp_0 : - 0 == 0.
Proof.
red; intros; zsimpl; auto with zarith.
Qed.
Theorem opp_succ : forall n, - (Z.succ n) == Z.pred (- n).
Proof.
intros; zsimpl; auto with zarith.
Qed.
Theorem abs_eq : forall n, 0 <= n -> Z.abs n == n.
Proof.
intros. red. rewrite Z.spec_abs. apply Zabs_eq.
rewrite <- Z.spec_0, <- spec_le; auto.
Qed.
Theorem abs_neq : forall n, n <= 0 -> Z.abs n == -n.
Proof.
intros. red. rewrite Z.spec_abs, Z.spec_opp. apply Zabs_non_eq.
rewrite <- Z.spec_0, <- spec_le; auto.
Qed.
Theorem sgn_null : forall n, n==0 -> Z.sgn n == 0.
Proof.
intros. red. rewrite Z.spec_sgn, Z.spec_0. rewrite Zsgn_null.
rewrite <- Z.spec_0; auto.
Qed.
Theorem sgn_pos : forall n, 0<n -> Z.sgn n == Z.succ 0.
Proof.
intros. red. rewrite Z.spec_sgn. zsimpl. rewrite Zsgn_pos.
rewrite <- Z.spec_0, <- spec_lt; auto.
Qed.
Theorem sgn_neg : forall n, n<0 -> Z.sgn n == Z.opp (Z.succ 0).
Proof.
intros. red. rewrite Z.spec_sgn. zsimpl. rewrite Zsgn_neg.
rewrite <- Z.spec_0, <- spec_lt; auto.
Qed.
(** Aliases *)
Definition t := Z.t.
Definition eq := Z.eq.
Definition zero := Z.zero.
Definition succ := Z.succ.
Definition pred := Z.pred.
Definition add := Z.add.
Definition sub := Z.sub.
Definition mul := Z.mul.
Definition opp := Z.opp.
Definition lt := Z.lt.
Definition le := Z.le.
Definition min := Z.min.
Definition max := Z.max.
Definition abs := Z.abs.
Definition sgn := Z.sgn.
End ZSig_ZAxioms.
|
