1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
|
(* -*- coq-prog-args: ("-emacs-U" "-nois") -*- *)
(************************************************************************)
(* v * The Coq Proof Assistant / The Coq Development Team *)
(* <O___,, * CNRS-Ecole Polytechnique-INRIA Futurs-Universite Paris Sud *)
(* \VV/ **************************************************************)
(* // * This file is distributed under the terms of the *)
(* * GNU Lesser General Public License Version 2.1 *)
(************************************************************************)
(* Typeclass-based relations, tactics and standard instances.
This is the basic theory needed to formalize morphisms and setoids.
Author: Matthieu Sozeau
Institution: LRI, CNRS UMR 8623 - UniversitÃcopyright Paris Sud
91405 Orsay, France *)
(* $Id: FSetAVL_prog.v 616 2007-08-08 12:28:10Z msozeau $ *)
Require Import Coq.Program.Program.
Require Import Coq.Classes.Init.
Set Implicit Arguments.
Unset Strict Implicit.
Notation "'relation' A " := (A -> A -> Prop) (at level 0).
Definition inverse A (R : relation A) : relation A := fun x y => R y x.
Lemma inverse_inverse : forall A (R : relation A), inverse (inverse R) = R.
Proof. intros ; unfold inverse. apply (flip_flip R). Qed.
Definition complement A (R : relation A) := fun x y => R x y -> False.
(** These are convertible. *)
Lemma complement_inverse : forall A (R : relation A), complement (inverse R) = inverse (complement R).
Proof. reflexivity. Qed.
(** We rebind relations in separate classes to be able to overload each proof. *)
Class Reflexive A (R : relation A) :=
reflexive : forall x, R x x.
Class Irreflexive A (R : relation A) :=
irreflexive : forall x, R x x -> False.
Class Symmetric A (R : relation A) :=
symmetric : forall x y, R x y -> R y x.
Class Asymmetric A (R : relation A) :=
asymmetric : forall x y, R x y -> R y x -> False.
Class Transitive A (R : relation A) :=
transitive : forall x y z, R x y -> R y z -> R x z.
Implicit Arguments Reflexive [A].
Implicit Arguments Irreflexive [A].
Implicit Arguments Symmetric [A].
Implicit Arguments Asymmetric [A].
Implicit Arguments Transitive [A].
Hint Resolve @irreflexive : ord.
(** We can already dualize all these properties. *)
Program Instance [ Reflexive A R ] => flip_reflexive : Reflexive A (flip R) :=
reflexive := reflexive (R:=R).
Program Instance [ Irreflexive A R ] => flip_irreflexive : Irreflexive A (flip R) :=
irreflexive := irreflexive (R:=R).
Program Instance [ Symmetric A R ] => flip_symmetric : Symmetric A (flip R).
Solve Obligations using unfold flip ; program_simpl ; apply symmetric ; eauto.
Program Instance [ Asymmetric A R ] => flip_asymmetric : Asymmetric A (flip R).
Solve Obligations using program_simpl ; unfold flip in * ; intros ; eapply asymmetric ; eauto.
Program Instance [ Transitive A R ] => flip_transitive : Transitive A (flip R).
Solve Obligations using unfold flip ; program_simpl ; eapply transitive ; eauto.
(** Have to do it again for Prop. *)
Program Instance [ Reflexive A (R : relation A) ] => inverse_reflexive : Reflexive A (inverse R) :=
reflexive := reflexive (R:=R).
Program Instance [ Irreflexive A (R : relation A) ] => inverse_irreflexive : Irreflexive A (inverse R) :=
irreflexive := irreflexive (R:=R).
Program Instance [ Symmetric A (R : relation A) ] => inverse_symmetric : Symmetric A (inverse R).
Solve Obligations using unfold inverse, flip ; program_simpl ; eapply symmetric ; eauto.
Program Instance [ Asymmetric A (R : relation A) ] => inverse_asymmetric : Asymmetric A (inverse R).
Solve Obligations using program_simpl ; unfold inverse, flip in * ; intros ; eapply asymmetric ; eauto.
Program Instance [ Transitive A (R : relation A) ] => inverse_transitive : Transitive A (inverse R).
Solve Obligations using unfold inverse, flip ; program_simpl ; eapply transitive ; eauto.
Program Instance [ Reflexive A (R : relation A) ] =>
reflexive_complement_irreflexive : Irreflexive A (complement R).
Next Obligation.
Proof.
apply H.
apply reflexive.
Qed.
Program Instance [ Irreflexive A (R : relation A) ] =>
irreflexive_complement_reflexive : Reflexive A (complement R).
Next Obligation.
Proof.
red ; intros.
apply (irreflexive H).
Qed.
Program Instance [ Symmetric A (R : relation A) ] => complement_symmetric : Symmetric A (complement R).
Next Obligation.
Proof.
red ; intros H'.
apply (H (symmetric H')).
Qed.
(** * Standard instances. *)
Ltac simpl_relation :=
try red ; unfold inverse, flip, impl, arrow ; program_simpl ; try tauto ;
repeat (red ; intros) ; try ( solve [ intuition ]).
Ltac obligations_tactic ::= simpl_relation.
(** Logical implication. *)
Program Instance impl_refl : ? Reflexive impl.
Program Instance impl_trans : ? Transitive impl.
(** Logical equivalence. *)
Program Instance iff_refl : ? Reflexive iff.
Program Instance iff_sym : ? Symmetric iff.
Program Instance iff_trans : ? Transitive iff.
(** Leibniz equality. *)
Program Instance eq_refl : ? Reflexive (@eq A).
Program Instance eq_sym : ? Symmetric (@eq A).
Program Instance eq_trans : ? Transitive (@eq A).
(** ** General tactics to solve goals on relations.
Each tactic comes in two flavors:
- a tactic to immediately solve a goal without user intervention
- a tactic taking input from the user to make progress on a goal *)
Definition relate A (R : relation A) : relation A := R.
Ltac relationify_relation R R' :=
match goal with
| [ H : context [ R ?x ?y ] |- _ ] => change (R x y) with (R' x y) in H
| [ |- context [ R ?x ?y ] ] => change (R x y) with (R' x y)
end.
Ltac relationify R :=
set (R' := relate R) ; progress (repeat (relationify_relation R R')).
Ltac relation_refl :=
match goal with
| [ |- ?R ?X ?X ] => apply (reflexive (R:=R) X)
| [ H : ?R ?X ?X |- _ ] => apply (irreflexive (R:=R) H)
| [ |- ?R ?A ?X ?X ] => apply (reflexive (R:=R A) X)
| [ H : ?R ?A ?X ?X |- _ ] => apply (irreflexive (R:=R A) H)
| [ |- ?R ?A ?B ?X ?X ] => apply (reflexive (R:=R A B) X)
| [ H : ?R ?A ?B ?X ?X |- _ ] => apply (irreflexive (R:=R A B) H)
| [ |- ?R ?A ?B ?C ?X ?X ] => apply (reflexive (R:=R A B C) X)
| [ H : ?R ?A ?B ?C ?X ?X |- _ ] => apply (irreflexive (R:=R A B C) H)
| [ |- ?R ?A ?B ?C ?D ?X ?X ] => apply (reflexive (R:=R A B C D) X)
| [ H : ?R ?A ?B ?C ?D ?X ?X |- _ ] => apply (irreflexive (R:=R A B C D) H)
end.
Ltac refl := relation_refl.
Ltac relation_sym :=
match goal with
| [ H : ?R ?X ?Y |- ?R ?Y ?X ] => apply (symmetric (R:=R) (x:=X) (y:=Y) H)
| [ H : ?R ?A ?X ?Y |- ?R ?A ?Y ?X ] => apply (symmetric (R:=R A) (x:=X) (y:=Y) H)
| [ H : ?R ?A ?B ?X ?Y |- ?R ?A ?B ?Y ?X ] => apply (symmetric (R:=R A B) (x:=X) (y:=Y) H)
| [ H : ?R ?A ?B ?C ?X ?Y |- ?R ?A ?B ?C ?Y ?X ] => apply (symmetric (R:=R A B C) (x:=X) (y:=Y) H)
| [ H : ?R ?A ?B ?C ?D ?X ?Y |- ?R ?A ?B ?C ?D ?Y ?X ] => apply (symmetric (R:=R A B C D) (x:=X) (y:=Y) H)
end.
Ltac relation_symmetric :=
match goal with
| [ |- ?R ?Y ?X ] => apply (symmetric (R:=R) (x:=X) (y:=Y))
| [ |- ?R ?A ?Y ?X ] => apply (symmetric (R:=R A) (x:=X) (y:=Y))
| [ |- ?R ?A ?B ?Y ?X ] => apply (symmetric (R:=R A B) (x:=X) (y:=Y))
| [ |- ?R ?A ?B ?C ?Y ?X ] => apply (symmetric (R:=R A B C) (x:=X) (y:=Y))
| [ |- ?R ?A ?B ?C ?D ?Y ?X ] => apply (symmetric (R:=R A B C D) (x:=X) (y:=Y))
end.
Ltac sym := relation_symmetric.
Ltac relation_trans :=
match goal with
| [ H : ?R ?X ?Y, H' : ?R ?Y ?Z |- ?R ?X ?Z ] =>
apply (transitive (R:=R) (x:=X) (y:=Y) (z:=Z) H H')
| [ H : ?R ?A ?X ?Y, H' : ?R ?A ?Y ?Z |- ?R ?A ?X ?Z ] =>
apply (transitive (R:=R A) (x:=X) (y:=Y) (z:=Z) H H')
| [ H : ?R ?A ?B ?X ?Y, H' : ?R ?A ?B ?Y ?Z |- ?R ?A ?B ?X ?Z ] =>
apply (transitive (R:=R A B) (x:=X) (y:=Y) (z:=Z) H H')
| [ H : ?R ?A ?B ?C ?X ?Y, H' : ?R ?A ?B ?C ?Y ?Z |- ?R ?A ?B ?C ?X ?Z ] =>
apply (transitive (R:=R A B C) (x:=X) (y:=Y) (z:=Z) H H')
| [ H : ?R ?A ?B ?C ?D ?X ?Y, H' : ?R ?A ?B ?C ?D ?Y ?Z |- ?R ?A ?B ?C ?D ?X ?Z ] =>
apply (transitive (R:=R A B C D) (x:=X) (y:=Y) (z:=Z) H H')
| [ H : ?R ?A ?B ?C ?D ?E ?X ?Y, H' : ?R ?A ?B ?C ?D ?E ?Y ?Z |- ?R ?A ?B ?C ?D ?E ?X ?Z ] =>
apply (transitive (R:=R A B C D E) (x:=X) (y:=Y) (z:=Z) H H')
end.
Ltac relation_transitive Y :=
match goal with
| [ |- ?R ?X ?Z ] =>
apply (transitive (R:=R) (x:=X) (y:=Y) (z:=Z))
| [ |- ?R ?A ?X ?Z ] =>
apply (transitive (R:=R A) (x:=X) (y:=Y) (z:=Z))
| [ |- ?R ?A ?B ?X ?Z ] =>
apply (transitive (R:=R A B) (x:=X) (y:=Y) (z:=Z))
| [ |- ?R ?A ?B ?C ?X ?Z ] =>
apply (transitive (R:=R A B C) (x:=X) (y:=Y) (z:=Z))
| [ |- ?R ?A ?B ?C ?D ?X ?Z ] =>
apply (transitive (R:=R A B C D) (x:=X) (y:=Y) (z:=Z))
end.
Ltac trans Y := relation_transitive Y.
(** To immediatly solve a goal on setoid equality. *)
Ltac relation_tac := relation_refl || relation_sym || relation_trans.
(** The [PER] typeclass. *)
Class PER (carrier : Type) (pequiv : relation carrier) :=
per_sym :> Symmetric pequiv ;
per_trans :> Transitive pequiv.
(** We can build a PER on the Coq function space if we have PERs on the domain and
codomain. *)
Program Instance [ PER A (R : relation A), PER B (R' : relation B) ] =>
arrow_per : PER (A -> B)
(fun f g => forall (x y : A), R x y -> R' (f x) (g y)).
Next Obligation.
Proof with auto.
constructor ; intros...
assert(R x0 x0) by (trans y0 ; [ auto | sym ; auto ]).
trans (y x0)...
Qed.
(** The [Equivalence] typeclass. *)
Class Equivalence (carrier : Type) (equiv : relation carrier) :=
equiv_refl :> Reflexive equiv ;
equiv_sym :> Symmetric equiv ;
equiv_trans :> Transitive equiv.
(** We can now define antisymmetry w.r.t. an equivalence relation on the carrier. *)
Class [ Equivalence A eqA ] => Antisymmetric (R : relation A) :=
antisymmetric : forall x y, R x y -> R y x -> eqA x y.
Program Instance [ eq : Equivalence A eqA, ? Antisymmetric eq R ] =>
flip_antisymmetric : ? Antisymmetric eq (flip R).
Solve Obligations using unfold inverse, flip ; program_simpl ; eapply @antisymmetric ; eauto.
Program Instance [ eq : Equivalence A eqA, ? Antisymmetric eq (R : relation A) ] =>
inverse_antisymmetric : ? Antisymmetric eq (inverse R).
Solve Obligations using unfold inverse, flip ; program_simpl ; eapply @antisymmetric ; eauto.
(** Leibinz equality [eq] is an equivalence relation. *)
Program Instance eq_equivalence : Equivalence A eq.
(** Logical equivalence [iff] is an equivalence relation. *)
Program Instance iff_equivalence : Equivalence Prop iff.
(** The following is not definable. *)
(*
Program Instance [ sa : Equivalence a R, sb : Equivalence b R' ] => equiv_setoid :
Equivalence (a -> b)
(fun f g => forall (x y : a), R x y -> R' (f x) (g y)).
*)
|
